Package	graphics.display
Class	public class TimelineTransition
Inheritance	TimelineTransition CoreTransition CoreAction Task Object

This transition check the frames in the timeline of a specific MovieClip reference and notify a finish and start events between two specific frames.

Example :

     package examples 
     {
         import graphics.display.TimelineTransition;
         
         import system.events.ActionEvent;
         
         import flash.display.MovieClip;
         import flash.display.Sprite;
         import flash.display.StageScaleMode;
         import flash.events.KeyboardEvent;
         import flash.ui.Keyboard;
         
         public dynamic class TimelineTransition01Example extends Sprite 
         {
             public function TimelineTransition01Example()
             {
                 // stage
                 
                 stage.scaleMode  = StageScaleMode.NO_SCALE ;
                 
                 stage.addEventListener( KeyboardEvent.KEY_DOWN , keyDown ) ;
                 
                 // MovieClip target with the three frame labels : 
                 // "start", "middle" and "finish"
                 
                 movieclip = getChildByName("mc") as MovieClip ;
                 
                 // timeline script
                 
                 timeline = new TimelineTransition( movieclip ) ;
                 
                 timeline.defaultIndex = 4 ; // by default stop the MovieClip in the frame index 4.
                 
                 timeline.addEventListener( ActionEvent.FINISH , finish ) ;
                 timeline.addEventListener( ActionEvent.RESUME , resume ) ;
                 timeline.addEventListener( ActionEvent.START  , start  ) ;
             }
             
             protected var movieclip:MovieClip ;
             protected var timeline:TimelineTransition ;
             
             protected function finish( e:ActionEvent ):void
             {
                 trace( "finish" ) ;
             }
             
             protected function keyDown( e:KeyboardEvent ):void
             {
                 var code:uint = e.keyCode ;
                 switch( code )
                 {
                     case Keyboard.UP :
                     {
                         timeline.startIndex  = "middle" ;
                         timeline.finishIndex = "finish" ;
                         timeline.run() ;
                         break ;
                     }
                     case Keyboard.DOWN :
                     {
                         timeline.startIndex  = "start" ;
                         timeline.finishIndex = "middle" ;
                         timeline.run() ;
                         break ;
                     }
                     case Keyboard.SPACE :
                     {
                         timeline.startIndex  = "start" ;
                         timeline.finishIndex = "finish" ;
                         timeline.run() ;
                         break ;
                     }
                     case Keyboard.LEFT :
                     {
                         if ( timeline.running )
                         { 
                             timeline.stop() ;
                         }
                         else if ( timeline.stopped )
                         {
                             timeline.resume() ;
                         }
                         else
                         {
                             timeline.start() ;
                         }
                         break ;
                     }
                 }
             }
             
             protected function resume( e:ActionEvent ):void
             {
                 trace( "resume" ) ;
             }
             
             protected function start( e:ActionEvent ):void
             {
                 trace( "start" ) ;
             }
         }
     }
     

---