Package	graphics.display
Class	public class TimelineScript
Inheritance	TimelineScript Object

The TimeLineScript class use composition to register script function over MovieClip timelines.

Example :

     package examples 
     {
         import graphics.display.TimelineScript;
         
         import flash.display.MovieClip;
         import flash.display.Sprite;
         import flash.display.StageAlign;
         import flash.display.StageScaleMode;
         import flash.events.KeyboardEvent;
         import flash.ui.Keyboard;
         import flash.utils.clearTimeout;
         import flash.utils.setTimeout;
         
         public dynamic class TimelineScriptExample extends Sprite 
         {
             public function TimelineScriptExample()
             {
                 // stage
                 
                 stage.align      = StageAlign.TOP_LEFT ;
                 stage.scaleMode  = StageScaleMode.NO_SCALE ;
                 
                 stage.addEventListener( KeyboardEvent.KEY_DOWN , keyDown ) ;
                 
                 // MovieClip target
                 
                 movieclip = getChildByName("mc") as MovieClip ;
                 
                 // timeline script
                 
                 timeline = new TimelineScript( movieclip , true ) ;
                 
                 timeline.put( "start"   , start ) ;
                 timeline.put( "middle"  , pause ) ;
                 timeline.put( "finish"  , finish ) ;
             }
             
             protected var id:uint ;
             protected var movieclip:MovieClip ;
             protected var timeline:TimelineScript ;
             
             protected function pause():void
             {
                 trace( "pause" ) ;
                 movieclip.stop() ;
                 if ( id )
                 {
                     clearTimeout( id ) ;
                 }
                 id = setTimeout( movieclip.play , 4000 ) ; // pause 4 s
             }
             
             protected function finish():void
             {
                 trace( "finish" ) ;
                 movieclip.stop() ;
             }
             
             protected function keyDown( e:KeyboardEvent ):void
             {
                 var code:uint = e.keyCode ;
                 switch( code )
                 {
                     case Keyboard.SPACE :
                     {
                         movieclip.gotoAndPlay(1) ; // start 
                         break ;
                     }
                     case Keyboard.UP :
                     {
                         timeline.remove( "middle" ) ;
                         break ;
                     }
                     case Keyboard.DOWN :
                     {
                         timeline.clear() ;
                         break ;
                     }
                 }
             }
             
             protected function start():void
             {
                 trace( "start" ) ;
             }
         }
     }
     

---