Package	system.ioc
Class	public class ObjectListener
Inheritance	ObjectListener Object

This object defines a listener definition in an object definition.

Example :

     import system.ioc.ObjectListener ;
     
     var init:Array = 
     [
         { dispatcher:"dispatcher1" , type:"change" , method:"handleEvent" } ,
         { dispatcher:"dispatcher2" , type:"change" , method:"handleEvent" } 
     ] ;
     
     var listeners:Array = ObjectListener.create( init ) ;
     
     trace( listeners ) ; 
     

Usage, in the IoC factory we can use the "listeners" attribute in the object definition to defines the object like a listener.

Example :

     import system.ioc.ObjectFactory ;
     
     var context:Object =
     [
         { 
             id        : "dispatcher1" ,
             type      : "flash.events.EventDispatcher" ,
             singleton : true
         }
         ,
         { 
             id        : "dispatcher2" ,
             type      : "flash.events.EventDispatcher" ,
             singleton : true
         }
         ,    
         { 
             id        : "listener"   ,
             type      : "examples.Listener" ,
             singleton : true ,
             listeners :
             [
                 { dispatcher:"dispatcher1" , type:"change" , method:"handleEvent" , useCapture:false, priority:0 , useWeakReference:true } ,  
                 { dispatcher:"dispatcher2" , type:"change" } 
             ]
         }    
     ] ;
     
     var factory:ObjectFactory = new ObjectFactory() ;
     
     factory.create( context ) ; 
     
     // 1 - target the callback "handleEvent" method in the listener object (all objects with methods can be a listener)
     
     var dispatcher1:EventDispatcher = factory.getObject("dispatcher1") ;
     
     dispatcher1.dispatchEvent( new Event( "change" ) ) ; // [object Listener] handleEvent [Event type="change" bubbles=false cancelable=false eventPhase=2]
     
     // 2 - target the listener object if implements the system.events.EventListener interface.
     
     var dispatcher2:EventDispatcher = factory.getObject("dispatcher2") ;
     
     dispatcher2.dispatchEvent( new Event( "change" ) ) ; // [object Listener] handleEvent [Event type="change" bubbles=false cancelable=false eventPhase=2]
     

In the previous example we implement the examples.Listener class :

     package examples
     {
         import flash.events.Event;
         
         import system.events.EventListener;
          
         public class Listener implements EventListener
         {
             public function Listener()
             {
                  // constructor
             }
             
             public function handleEvent( e:Event ):void
             {
                 trace( this + " handleEvent " + e ) ;
             }
         }
     }
     

---