Package	graphics.transitions
Class	public class TweenTo
Inheritance	TweenTo TweenUnit Motion CoreTransition CoreAction Task Object

Example :

     package examples 
     {
         import graphics.Align;
         import graphics.FillStyle;
         import graphics.LineStyle;
         import graphics.drawing.Pen;
         import graphics.drawing.RectanglePen;
         import graphics.easings.bounceOut;
         import graphics.transitions.TweenTo;
         
         import flash.display.Shape;
         import flash.display.Sprite;
         import flash.display.StageScaleMode;
         import flash.events.KeyboardEvent;
         import flash.ui.Keyboard;
         
         public class TweenToExample extends Sprite
         {
             public function TweenToExample()
             {
                 /// stage
                 
                 stage.scaleMode = StageScaleMode.NO_SCALE ;
                 
                 stage.addEventListener( KeyboardEvent.KEY_DOWN , keyDown ) ;
                 
                 /// build and draw the shape
                 
                 var shape:Shape = new Shape() ;
                 var pen:Pen     = new RectanglePen( shape ) ;
                 
                 pen.fill = new FillStyle(0xFFFFFF) ;
                 pen.line = new LineStyle(1,0x999999) ;
                 pen.draw(0,0,32,32,Align.CENTER) ;
                 
                 shape.x = 50 ;
                 shape.y = 50 ;
                 
                 addChild( shape ) ;
                 
                 // initialize and run the tween
                 
                 var to:Object =
                 {
                     x        : 700 ,
                     y        : 250 ,
                     rotation : 180
                 };
                 
                 tween = new TweenTo( shape, to, bounceOut, 1.5, true , true ) ;
             }
             
             public var tween:TweenTo ;
             
             protected function keyDown( e:KeyboardEvent ):void
             {
                 var code:uint = e.keyCode ;
                 switch( code )
                 {
                     case Keyboard.UP :
                     {
                         tween.duration = 1 ;
                         tween.run( { x : 50 , y : 50 , rotation : 0 } ) ;
                         break ;
                     }
                     default :
                     {
                         tween.duration = 1.5 ;
                         tween.to = { x : 700 , y : 250 , rotation : 180 } ;
                         tween.run() ;
                         break ;
                     }
                 }
             }
         }
     }