Package	graphics.drawing
Class	public dynamic class TrianglePen
Inheritance	TrianglePen Pen flash.utils.Proxy

Draw a triangle with the A, B and C points in the 2D space. ab and ac are the lengths to defines the base of the shape.

Example :

     package examples 
     {
         import graphics.Align;
         import graphics.FillStyle;
         import graphics.LineStyle;
         
         import graphics.drawing.RectanglePen;
         import graphics.drawing.TrianglePen;
         
         import flash.display.Shape;
         import flash.display.Sprite;
         import flash.events.KeyboardEvent;
         import flash.ui.Keyboard;
         
         public class ExampleTrianglePen extends Sprite 
         {
             public function ExampleTrianglePen()
             {
                 var container:Sprite = new Sprite() ;
                 
                 container.x = 740/2 ;
                 container.y = 200   ;
                 
                 addChild( container ) ;
                 
                 ///////////////////////////////
                 
                 a = new Shape() ;
                 b = new Shape() ;
                 c = new Shape() ;
                 
                 var rec:RectanglePen ;
                 
                 rec = new RectanglePen( a ) ;
                 rec.fill  = new FillStyle( 0xFFFFFF ) ;
                 rec.draw( 0 , 0 , 5 , 5 , Align.CENTER ) ;
                 
                 rec = new RectanglePen( b ) ;
                 rec.fill  = new FillStyle( 0xFFFFFF ) ;
                 rec.draw( 0 , 0 , 5 , 5 , Align.CENTER ) ;
                 
                 rec = new RectanglePen( c ) ;
                 rec.fill  = new FillStyle( 0xFFFFFF ) ;
                 rec.draw( 0 , 0 , 5 , 5 , Align.CENTER ) ;
                 
                 ///////////////////////////////
                 
                 var canvas:Shape = new Shape() ;
                 
                 container.addChild( canvas ) ;
                 container.addChild( a ) ;
                 container.addChild( b ) ;
                 container.addChild( c ) ;
                 
                 pen       = new TrianglePen( canvas.graphics, 200, 200, 90, 90, 0, 0) ;
                 pen.fill  = new FillStyle( 0x3F65FC , 0.6 ) ;
                 pen.line  = new LineStyle( 2, 0xFFFFFF ) ;
                 
                 pen.draw() ;
                 
                 update() ;
                 
                 stage.addEventListener( KeyboardEvent.KEY_DOWN , keyDown ) ;
             }
             
             public var a:Shape ;
             public var b:Shape ;
             public var c:Shape ;
             
             public var pen:TrianglePen ;
             
             public function keyDown( e:KeyboardEvent ):void
             {
                 var code:uint = e.keyCode ;
                 switch( code )
                 {
                     case Keyboard.LEFT :
                     {
                         pen.rotation -= 10 ;
                         pen.draw() ;
                         break ;
                     }
                     case Keyboard.RIGHT :
                     {
                         pen.rotation += 10 ;
                         pen.draw() ;
                         break ;
                     }
                     case Keyboard.UP :
                     {
                         pen.angle -= 10 ;
                         pen.draw() ;
                         break ;
                     }
                     case Keyboard.DOWN :
                     {
                         pen.angle += 10 ;
                         pen.draw() ;
                         break ;
                     }
                 }
                 trace( "angle : " + pen.angle + " rotation:" + pen.rotation ) ;
                 update() ;
             }
             
             public function update():void
             {
                 a.x = pen.a.x ;
                 a.y = pen.a.y ;
                 
                 b.x = pen.b.x ;
                 b.y = pen.b.y ; 
                 
                 c.x = pen.c.x ;
                 c.y = pen.c.y ; 
             }
         }
     }
     

---