Package	graphics.display
Class	public class TimelineInspector
Inheritance	TimelineInspector CoreEventDispatcher Object

Example :

     package examples 
     {
         import graphics.display.TimelineInspector;
         import graphics.events.FrameLabelEvent;
         
         import flash.display.FrameLabel;
         import flash.display.MovieClip;
         import flash.display.Sprite;
         import flash.display.StageAlign;
         import flash.display.StageScaleMode;
         import flash.events.MouseEvent;
         import flash.utils.setTimeout;
         
         public dynamic class TestTimelineInspector extends Sprite
         {
              public function TestTimelineInspector()
              {
                  // stage
                  
                  stage.align      = StageAlign.TOP_LEFT ;
                  stage.scaleMode  = StageScaleMode.NO_SCALE ;
                  
                  // target
                  
                  mc               = getChildByName("mc") as MovieClip ; // MovieClip in the stage of the application
                  mc.useHandCursor = true ;
                  mc.buttonMode    = true ;
                  
                  mc.addEventListener( MouseEvent.CLICK , click ) ;
                  
                  trace("Click the movieclip to start the example.") ;
                  
                  // timeline inspector
                  
                  var inspector:TimelineInspector = new TimelineInspector( mc , true ) ;
                  inspector.addEventListener( FrameLabelEvent.FRAME_LABEL , frameLabel ) ;
                  
              }
              
              public var mc:MovieClip ;
              
              public function click( e:MouseEvent ):void
              {
                  mc.play() ;
              }
              
             public function frameLabel( e:FrameLabelEvent ):void
             {
                 var frame:FrameLabel = e.frameLabel ;
                 trace( "progress :: " + frame.frame + " : " + frame.name ) ;
                 switch( frame.name )
                 {
                     case "finish" :
                     {
                         mc.stop() ;
                         break ;
                     }
                     case "middle" :
                     {
                         mc.stop() ;
                         setTimeout(mc.play, 5000) ; // pause 5 seconds
                         break ;
                     }
                 }
             }
         }
     }